[RFC,4/4] scripts: add stackdelta script

Commit Message

Rasmus Villemoes June 21, 2015, 1:10 a.m. UTC

This adds a simple perl script for reading two files as produced by
the stackusage script and computing the changes in stack usage. For
example:

$ scripts/stackusage -o /tmp/old.su -- CC=gcc-4.7 -j8 fs/ext4/
$ scripts/stackusage -o /tmp/new.su -- CC=gcc-5.0 -j8 fs/ext4/
$ scripts/stackdelta /tmp/{old,new}.su | sort -k5,5g

shows that gcc 5.0 generally produces less stack-hungry code than gcc
4.7. Obviously, the script can also be used for measuring the effect
of commits, .config tweaks or whatnot.

Signed-off-by: Rasmus Villemoes <[e-mail]>
---
 scripts/stackdelta | 55 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100755 scripts/stackdelta

Comments

Rasmus Villemoes June 22, 2015, 7:39 a.m. UTC | #1

On Sun, Jun 21 2015, Rasmus Villemoes <[e-mail]> wrote:

> +
> +my $old = read_stack_usage_file($ARGV[0]);
> +my $new = read_stack_usage_file($ARGV[1]);
> +my @common = grep {exists $new->{$_}} keys %$old;
> +print join(",", keys %old) . "\n";

Bah, that print is leftover from debugging. Please pretend it's not
there.

Rasmus
--
To unsubscribe from this list: send the line "unsubscribe linux-kbuild" in

Patch

diff --git a/scripts/stackdelta b/scripts/stackdelta
new file mode 100755
index 000000000000..18417098a378
--- /dev/null
+++ b/scripts/stackdelta
@@ -0,0 +1,55 @@ 
+#!/usr/bin/perl
+
+# Read two files producesd by the stackusage script, and show the
+# delta between them.
+#
+# Currently, only shows changes for functions listed in both files. We
+# could add an option to show also functions which have vanished or
+# appeared (which would often be due to gcc making other inlining
+# decisions).
+#
+# Another possible option would be a minimum absolute value for the
+# delta.
+
+sub read_stack_usage_file {
+    my %su;
+    my $f = shift;
+    open(my $fh, '<', $f)
+	or die "cannot open $f: $!";
+    while (<$fh>) {
+	chomp;
+	my ($file, $func, $size, $type) = split;
+	# Old versions of gcc (at least 4.7) have an annoying quirk in
+	# that a (static) function whose name has been changed into
+	# for example ext4_find_unwritten_pgoff.isra.11 will show up
+	# in the .su file with a name of just "11". Since such a
+	# numeric suffix is likely to change across different
+	# commits/compilers/.configs or whatever else we're trying to
+	# tweak, we can't really track those functions, so we just
+	# silently skip them.
+	#
+	# Newer gcc (at least 5.0) report the full name, so again,
+	# since the suffix is likely to change, we strip it.
+	next if $func =~ m/^[0-9]+$/;
+	$func =~ s/\..*$//;
+	$su{"${file}\t${func}"} = {size => $size, type => $type};
+    }
+    close($fh);
+    return \%su;
+}
+
+@ARGV == 2
+    or die "usage: $0 <old> <new>";
+
+my $old = read_stack_usage_file($ARGV[0]);
+my $new = read_stack_usage_file($ARGV[1]);
+my @common = grep {exists $new->{$_}} keys %$old;
+print join(",", keys %old) . "\n";
+for (@common) {
+    my $x = $old->{$_}{size};
+    my $y = $new->{$_}{size};
+    my $delta = $y - $x;
+    if ($delta) {
+	printf "%s\t%d\t%d\t%+d\n", $_, $x, $y, $delta;
+    }
+}