[2/6] tests/qemu-iotests/meson.build: Improve the indentation

Commit Message

Thomas Huth Feb. 8, 2022, 10:13 a.m. UTC

By using subdir_done(), we can get rid of one level of indentation
in this file. This will make it easier to add more conditions to
skip the iotests in future patches.

Signed-off-by: Thomas Huth <[e-mail]>
---
 tests/qemu-iotests/meson.build | 61 ++++++++++++++++++----------------
 1 file changed, 32 insertions(+), 29 deletions(-)

Comments

Philippe Mathieu-Daudé Feb. 8, 2022, 10:51 a.m. UTC | #1

On 8/2/22 11:13, Thomas Huth wrote:
> By using subdir_done(), we can get rid of one level of indentation
> in this file. This will make it easier to add more conditions to
> skip the iotests in future patches.
> 
> Signed-off-by: Thomas Huth <[e-mail]>
> ---
>   tests/qemu-iotests/meson.build | 61 ++++++++++++++++++----------------
>   1 file changed, 32 insertions(+), 29 deletions(-)

Reviewed-by: Philippe Mathieu-Daudé <[e-mail]>

Hanna Czenczek Feb. 8, 2022, noon UTC | #2

On 08.02.22 11:13, Thomas Huth wrote:
> By using subdir_done(), we can get rid of one level of indentation
> in this file. This will make it easier to add more conditions to
> skip the iotests in future patches.
>
> Signed-off-by: Thomas Huth <[e-mail]>
> ---
>   tests/qemu-iotests/meson.build | 61 ++++++++++++++++++----------------
>   1 file changed, 32 insertions(+), 29 deletions(-)

Reviewed-by: Hanna Reitz <[e-mail]>

Patch

diff --git a/tests/qemu-iotests/meson.build b/tests/qemu-iotests/meson.build
index 5be3c74127..e1832c90e0 100644
--- a/tests/qemu-iotests/meson.build
+++ b/tests/qemu-iotests/meson.build
@@ -1,30 +1,33 @@ 
-if have_tools and targetos != 'windows'
-  qemu_iotests_binaries = [qemu_img, qemu_io, qemu_nbd, qsd]
-  qemu_iotests_env = {'PYTHON': python.full_path()}
-  qemu_iotests_formats = {
-    'qcow2': 'quick',
-    'raw': 'slow',
-    'qed': 'thorough',
-    'vmdk': 'thorough',
-    'vpc': 'thorough'
-  }
-
-  foreach k, v : emulators
-    if k.startswith('qemu-system-')
-      qemu_iotests_binaries += v
-    endif
-  endforeach
-  foreach format, speed: qemu_iotests_formats
-    if speed == 'quick'
-      suites = 'block'
-    else
-      suites = ['block-' + speed, speed]
-    endif
-    test('qemu-iotests ' + format, sh, args: [files('../check-block.sh'), format],
-         depends: qemu_iotests_binaries, env: qemu_iotests_env,
-         protocol: 'tap',
-         suite: suites,
-         timeout: 0,
-         is_parallel: false)
-  endforeach
+if not have_tools or targetos == 'windows'
+  subdir_done()
 endif
+
+qemu_iotests_binaries = [qemu_img, qemu_io, qemu_nbd, qsd]
+qemu_iotests_env = {'PYTHON': python.full_path()}
+qemu_iotests_formats = {
+  'qcow2': 'quick',
+  'raw': 'slow',
+  'qed': 'thorough',
+  'vmdk': 'thorough',
+  'vpc': 'thorough'
+}
+
+foreach k, v : emulators
+  if k.startswith('qemu-system-')
+    qemu_iotests_binaries += v
+  endif
+endforeach
+
+foreach format, speed: qemu_iotests_formats
+  if speed == 'quick'
+    suites = 'block'
+  else
+    suites = ['block-' + speed, speed]
+  endif
+  test('qemu-iotests ' + format, sh, args: [files('../check-block.sh'), format],
+       depends: qemu_iotests_binaries, env: qemu_iotests_env,
+       protocol: 'tap',
+       suite: suites,
+       timeout: 0,
+       is_parallel: false)
+endforeach